[ErikPshat]

Делаем полную базу RAP/RIF для установки на PS3 с HAN/HEN

Что требуется?

• Установленная со всеми особыми требованиями PS3 Tools Collection custom with icons

1. Зайдите в папку C:\PS3\ps3tools\tools\PsnStuff\ и запустите там батник make_lite_database.bat
2. На выходе получите самую свежую базу RAP в свежем текстовом файлике database_lite_new.txt
3. Затем обновляете этот файлик под названием database_lite.txt в папке MPHT/Tools/ на свежий, согласно инструкции ниже:

1. Скачиваем и устанавливаем последнюю версию MPHT - Make Pkg Han Tool
2. Идём и открываем эту папку программы C:\MPHT
3. Копируем в эту папку ваши файлы act.dat и idps.hex (без них вы не сможете подписать RAP в RIF под вашу консоль).
4. Жмём правой кнопкой в пустом месте этой папки и в контекстном меню выбираем "Создать -> Текстовый документ".
5. В папке создастся новый пустой файл Текстовый документ.txt
6. Открываем его, лучше всего, в бесплатном и всеми любимом текстовом редакторе Notepad++
7. Теперь, из спойлера ниже, выделяем мышкой весь код от начала до конца и копируем (CTRL+C):
   
   Скрипт конвертации:

   @echo off
   SetLocal EnableExtensions EnableDelayedExpansion
   echo.
   echo. Do you want to create an RAP database?
   echo. If Yes - press any key. If No - close this window.
   echo.
   pause
   echo.
   echo Creating RAP files from DataBase...
   if exist RAPS del /q "RAPS\*.*"
   if not exist RAPS md RAPS
   for /f "usebackq tokens=1,2 delims=;" %%A in ("tools\database_lite.txt") do (
   set /a n+=1
   echo !n!. RAP NAME: %%A; Key: %%B
   echo.>"RAPS\%%A"
   "tools\sfk" echo %%B +hextobin +setbytes "RAPS\%%A" 0 -yes > nul
   )
   echo.
   echo Done. !n! RAP files successfully created in the "RAPS" folder.
   echo Do you want to convert RAP files to RIF?
   echo If Yes - press any key. If No - close this window.
   echo.
   pause
   if not exist act.dat (
   echo Not found act.dat. Please paste file act.dat in this folder...
   goto end
   ) else (
   if not exist idps.hex (
   echo Not found idps.hex. Please paste file idps.hex in this folder...
   goto end
   )
   if exist exdata del /q exdata\*.*
   if not exist exdata md exdata
   echo.
   echo Converting RAP files to RIF
   set rap=RAPS\*.rap
   for %%I in (!rap!) do (
   echo | tools\ps3xploit_rifgen_edatresign %%I > nul
   set rap=%%I
   set /a rif+=1
   echo !rif!. Converting !rap:~5! && move /y RAPS\%%~nI.rif exdata > nul
   )
   echo.
   echo Done. !rif! RIF files successfully created in the "exdata" folder.
   echo Do you want to pack RIF files in PKG?
   echo If Yes - press any key. If No - close this window.
   echo.
   pause
   echo.
   move signed_act.dat exdata\act.dat > nul
   set "i=1"
   for /l %%i in (1, 1, 5) do (
   set "c=!rif:~%%i!"
   if defined c set /a "i+=1"
   )
   if !i!==5 set RID=RIF000-INSTALLER_00-RIF00000000!rif!00000
   if !i!==4 set RID=RIF000-INSTALLER_00-RIF000000000!rif!0000
   if !i!==3 set RID=RIF000-INSTALLER_00-RIF0000000000!rif!000
   if !i!==2 set RID=RIF000-INSTALLER_00-RIF00000000000!rif!00
   if !i!==1 set RID=RIF000-INSTALLER_00-RIF000000000000!rif!0
   set CID=!RID:~0,36!
   echo Creating PKG from RIF and ACT.DAT     please wait...
   tools\make_package_license -c !CID! exdata !CID!.pkg
   echo | tools\ps3xploit_rifgen_edatresign "!CID!.pkg"
   del /q "!CID!.pkg"
   if exist "!CID!_signed.pkg" (
   if not exist BACKUP md BACKUP
   move /y "!CID!_signed.pkg" BACKUP > nul
   )
   ren "!CID!.pkg_signed.pkg" "!CID!_signed.pkg"
   echo.
   echo DONE. Signed PKG created: "!CID!_signed.pkg"
   echo.
   )
   :end
   pause

8. Затем, ставим курсор в наш новый открытый Текстовый документ и вставляем (CTRL+V) весь скопированный ранее код из буфера обмена.
9. Нажимаем в меню "Файл -> Сохранить как..." и сохраняем в этой же папке как, например - Текстовый документ.BAT
   Закрываем текстовой редактор.
10. Запускаем созданный БАТник и наблюдаем за процессом создания новой базы данных РАП-ов. Внимание, во время работы скрипта не щёлкайте в окне консоли и не открывайте файлы, создаваемые во время работы - это может привести к пропуску создания рапов и рифов или к ошибкам при их создании, если файл был занят вами, открыт в какой-то программе.
11. Пару раз программа будет просить нажать любую кнопку для продолжения операции, тогда просто нажмите любую клавишу на клавиатуре.
    Если вам не охота продолжать процесс, тогда просто закройте окно консоли.

• P.S. Папки RAPS и exdata с созданными RAP и RIF я не стал удалять в коде, на тот случай, если прога не сможет все RIF упаковать в PKG. Впоследствии вы можете их удалить вручную.
• P.P.S Кроме того, вы можете просто взять папку с базой RAP, переименовать её в exdata и закинуть в корень флешки или на плойку по пути /dev_hdd0/exdata/, тогда HEN сам найдёт на плойке act.dat в активном профиле и ваш уникальный idps.hex плойки, и при запуске игры сам же зашифрует необходимый в RIF в вашем активном профиле, который активируется при активации консоли.

Отчёт о работе скрипта:

Запустил скрипт, он где-то за 5 минут создал базу рап, после создания РАП-ов попросил нажать кнопочку, пошло шифрование RAP в RIF, я лёг спать, а когда через 7 часов проснулся, уже все RIF-ы были созданы, просило нажать любую клавишу для упаковки в PKG, ну и запаковало всё где-то за 5 минут.
В ообщем все 15333 RIF + 1 act.dat упаковались успешно в файл RIF000-INSTALLER_00-RIF0000000015333_signed.pkg и вот результат:

RAPs 15284.png

P.S. Почему 15333, а не 16303 как было ранее? - Потому что в новой базе были вычищены все левые "Invalid RAP", "Warning RAP", ошибочные RAP из 8-10-12-15 байт, хотя должны быть строго по 16 байт, а так же, были удалены множественные дублирующиеся строки.
В зависимости от постоянных поправок в базе, количество RAP/RIF может меняться, как в сторону увеличения, так и уменьшения.